Sub MyIniFileSet()
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Rem 「.iniファイル」（構成設定ファイル）値書き込み処理
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Dim myWord As Variant
  Dim myIniFile As String
  '
  myIniFile = "C:\Documents and Settings\User\My Documents\Zzz\MyIniFile.ini"
  Set myWord = CreateObject("Word.Application")
  '
  myWord.System.PrivateProfileString(myIniFile, "MyMacro", "DefaultFile") = Application.DefaultFilePath & "\" & "Test000.txt"
  myWord.Quit
  Set myWord = Nothing
End Sub ' MyIniFileSet *----*----*    *----*----*    *----*----*    *----*----*

Sub MyIniFileGet()
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Rem 「.iniファイル」（構成設定ファイル）値読み込み処理
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Dim myWord As Variant
  Dim myIniFile As String
  '
  myIniFile = "C:\Documents and Settings\User\My Documents\Zzz\MyIniFile.ini"
  Set myWord = CreateObject("Word.Application")
  '
  myIniFile = myWord.System.PrivateProfileString(myIniFile, "MyMacro", "DefaultFile")
  myWord.Quit
  Set myWord = Nothing
  '
  If Len(myIniFile) <> 0 Then
    MsgBox myIniFile
  End If
End Sub ' MyIniFileGet *----*----*    *----*----*    *----*----*    *----*----*

Sub MyNextDefaultFileName()
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Rem 「名前を付けて保存」ダイアログボックス表示処理
  Rem  （ファイルを順次選択する。）
  Rem 作譜：Hitrock Camellia Shinopy
  Rem 言語：Excel VBA
  Rem 機能...
  Rem 「.iniファイル」の設定値の次のファイル名を既定値として[ファイル名]に指定する。
  Rem 注記...
  Rem   Microsoft Wordの機能を利用している。
  Rem   myIniFileに構成設定ファイルの保存先を設定する。
  Rem   myFileにダイアログボックスで最初に選択したいフォルダ名・ファイル名を指定する。
  Rem 履歴...
  Rem   第1版：2008/10/01 作成。
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Dim myTitle As String
  Dim myIniFile As String
  Dim myWord As Variant
  Dim myDefaultFile As String
  Dim myFolder As String
  Dim myFile As String
  Dim myFiles As String
  Dim myFlag As Boolean
  '
  Dim myText As String
  Dim myStatusBar As String
  Dim myFileName As Variant
  '
  myTitle = "MyNextDefaultFileName"
  ' myIniFile = "C:\Documents and Settings\User\My Documents\Zzz\MyIniFile.ini"
  myIniFile = "C:\Users\User\Documents\Zzz\MyIniFile.ini"
  Set myWord = CreateObject("Word.Application")
  '
MyGetNextFileNameSubEntry:
  myDefaultFile = myWord.System.PrivateProfileString(myIniFile, "MyMacro", "DefaultFile")
  '
  If Len(myDefaultFile) = 0 Then
    myFile = Application.DefaultFilePath & "\" & "Test000.txt"
    MsgBox ".iniファイルの不備です。取り敢えず、既定値をセットします" & vbCrLf _
      & myFile
    '
    myWord.System.PrivateProfileString(myIniFile, "MyMacro", "DefaultFile") = myFile
    myWord.Quit
    Set myWord = Nothing
    Exit Sub
  End If
  myWord.Quit
  Set myWord = Nothing
  '
  myFolder = Left(myDefaultFile, InStrRev(myDefaultFile, "\") - 1)
  myFile = Replace(myDefaultFile, myFolder & "\", "")
  '
  ChDir (myFolder)
  myFolder = myFolder & "\*.txt"
  '
  myFlag = False
  myFiles = Dir(myFolder)
  Do While myFiles <> ""
    myDefaultFile = myFiles
    If myFiles = myFile Then
      myFlag = True
    End If
    If myFiles > myFile Then Exit Do
    myFiles = Dir()
  Loop
  If myFlag <> True Then
    myDefaultFile = ""
  End If
  '
  myText = "ファイルを選択して下さい。"
  myStatusBar = myText
  Application.StatusBar = myTitle & "：" & myStatusBar
  '
  myFileName = Application.GetSaveAsFilename(InitialFileName:=myDefaultFile, _
                                             FileFilter:="テキストファイル,*.txt", _
                                             Title:=myText, FilterIndex:=1)
  If TypeName(myFileName) = "Boolean" Then
    Exit Sub
  End If
  '
  Set myWord = CreateObject("Word.Application")
  myWord.System.PrivateProfileString(myIniFile, "MyMacro", "DefaultFile") = myFileName
  myWord.Quit
  Set myWord = Nothing
End Sub ' MyNextDefaultFileName *----*----*    *----*----*    *----*----*    *----*----*