Sub MyFldCkBox()
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Rem チェックボックス記号表示フィールド切替処理
  Rem 作譜：Hitrock Camellia Shinopy
  Rem 言語：Word VBA
  Rem 機能...
  Rem   文書上にフィールドを挿入して、赤い色のチェックボックスを表示しておき、
  Rem   これをダブルクリックして、チェックボックスの表示を切り替える。
  Rem 注記...
  Rem   文書上に下記の通り作成したフィールドを挿入する必要がある。
  Rem   1. 文書上のチェックボックスを表示したい箇所にカーソルを置き、
  Rem      [Ctrl]+[F9]を押して、「{}」を表示させる。
  Rem   2. 「{}」の中に「MACROBUTTON MyFldCkBox □」とフィールドコードを入力する。
  Rem      「□」は、フォントが[MS Pゴシック]で、[Unicode(16進)]の文字コード[2610]を挿入する。
  Rem     （メニューバーの[挿入]-[記号と特殊文字]でオフ状態のチェックボックスを選択する。）
  Rem   3. 入力したフィールドコード全体をマウスで選択して、
  Rem      フォントに[MS Pゴシック]（[MS ゴシック]でも可）を指定する。
  Rem      （フォントによっては不可。例：[Courier New]ではチェックボックスが文字化けする。）
  Rem      また、フォントのに赤を指定する。
  Rem   4. 右クリックして、[フィールドコードの表示／非表示]をクリックする。
  Rem      「□」だけが表示される。
  Rem   5. 文書上の「□」が表示されたフィールドをダブルクリックすると、
  Rem      オン／オフ状態のチェックボックスが交互に表示される。
  Rem 履歴...
  Rem   第01版：2006/07/03 作成。
  Rem   第02版：2008/03/30 [初期設定処理（クリック回数変更）]を追加。
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Dim myRange As Range
  '
  Set myRange = Selection.Fields(1).Code
  '
  If myRange.Text = "MACROBUTTON MyFldCkBox " & ChrW(9744) Then
    myRange.Text = "MACROBUTTON MyFldCkBox " & ChrW(9745)
  Else
    myRange.Text = "MACROBUTTON MyFldCkBox " & ChrW(9744)
  End If
  '
  With Selection
    .Fields(1).Update
    .Fields(1).ShowCodes = False
    .Font.Color = wdColorRed
    .SetRange Selection.End, Selection.End
  End With
End Sub ' MyFldCkBox *----*----*    *----*----*    *----*----*    *----*----*

Sub MyFldCkBoxInit()
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Rem 初期設定処理（クリック回数変更）
  Rem 注記...
  Rem   1. MyFldCkBoxを実行する上で必要であれば実行する。
  Rem   2. Microsoft WordのMACROBUTTON または GOTOBUTTONフィールドを
  Rem      実行するために必要なクリック回数の既定値は、2。
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  '
  Rem MACROBUTTON または GOTOBUTTONフィールドを実行するために必要なクリック回数を、1に設定します。
  Options.ButtonFieldClicks = 1
End Sub ' MyFldCkBoxInit *----*----*    *----*----*    *----*----*    *----*----*