Sub MyGoogleSearch()
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Rem 選択文字列Google検索処理
  Rem 作譜：Hitrock Camellia Shinopy
  Rem 言語：Word VBA
  Rem 機能...
  Rem   選択文字列をGoogleで検索する。
  Rem 注記...
  Rem   1. 参照設定なしでも実行可｡
  Rem   2. 佐藤信正：著『VBScript実用プログラミング・テクニック』メディア・テック出版：刊の
  Rem      「Part4 各種データと通信の処理」「[16]Google検索コマンドを作る」の
  Rem      「Google.vbs」から引用し、Word VBA用に変更した。
  Rem 履歴...
  Rem   第01版：2007/04/06：作成。
  Rem   第02版：2014/07/10：VariantをObjectに変更。
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Rem 参照設定する場合...
  Rem   Windows Script Host Object Model
  Rem   Microsoft Script Control
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  Dim myString As String
  Dim mySc As Object ' ScriptControl
  Dim myJScript As Object ' JScriptTypeInfo
  Dim myQuery As String
  Dim myData As String
  Dim myShell As Object ' IWshRuntimeLibrary.WshShell
  Rem *----*----*    *----*----*    *----*----*    *----*----*
  myString = Selection.Range.Text
  myString = Replace(myString, vbCrLf, " ")
  myString = Replace(myString, vbCr, " ")
  myString = Replace(myString, vbLf, " ")
  myString = Replace(myString, vbFormFeed, " ")
  myString = Replace(myString, vbVerticalTab, " ")
  myString = Trim(myString)
  '
  Set mySc = CreateObject("ScriptControl")
  mySc.Language = "JScript"
  '
  Set myJScript = mySc.CodeObject
  myQuery = "http://www.google.co.jp/search?q=" & myString
  myData = myJScript.encodeURI(myQuery)
  '
  Set myShell = CreateObject("WScript.Shell")
  myShell.Run (myData)
End Sub ' MyGoogleSearch *----*----*    *----*----*    *----*----*    *----*----*